PICARD COLLECTRNASEQMETRICS

Run picard CollectRnaSeqMetrics to generate QC metrics for RNA-seq data.

Example

This wrapper can be used in the following way:

rule alignment_summary:
    input:
        # BAM aligned, splicing-aware, to reference genome
        bam="mapped/a.bam",
        # Annotation file containing transcript, gene, and exon data
        refflat="annotation.refFlat"
    output:
        "results/a.rnaseq_metrics.txt"
    params:
        # strand is optional (defaults to NONE) and pertains to the library preparation
        # options are FIRST_READ_TRANSCRIPTION_STRAND, SECOND_READ_TRANSCRIPTION_STRAND, and NONE
        strand="NONE",
        # optional additional parameters, for example,
        extra="VALIDATION_STRINGENCY=STRICT"
    log:
        "logs/picard/rnaseq-metrics/a.log"
    # optional specification of memory usage of the JVM that snakemake will respect with global
    # resource restrictions (https://snakemake.readthedocs.io/en/latest/snakefiles/rules.html#resources)
    # and which can be used to request RAM during cluster job submission as `{resources.mem_mb}`:
    # https://snakemake.readthedocs.io/en/latest/executing/cluster.html#job-properties
    resources:
        mem_mb=1024
    wrapper:
        "https://raw.githubusercontent.com/brcopeland/snakemake-wrappers/picard_collectrnaseqmetrics/bio/picard/collectrnaseqmetrics"
        #"0.75.0/bio/picard/collectrnaseqmetrics"

Note that input, output and log file paths can be chosen freely. When running with

snakemake --use-conda

the software dependencies will be automatically deployed into an isolated environment before execution.

Software dependencies

• picard==2.25.4
• snakemake-wrapper-utils==0.1.3

Input/Output

Input:

• BAM file of RNA-seq data aligned to genome
• REF_FLAT formatted file of transcriptome annotations

Output:

• RNA-Seq metrics text file

Notes

• For more information, see https://broadinstitute.github.io/picard/command-line-overview.html#CollectRnaSeqMetrics.

Authors

• Brett Copeland

Code

__author__ = "Brett Copeland"
__copyright__ = "Copyright 2021, Brett Copeland"
__email__ = "brcopeland@ucsd.edu"
__license__ = "MIT"


from snakemake.shell import shell
from snakemake_wrapper_utils.java import get_java_opts

strand = snakemake.params.get("strand", "NONE")
extra = snakemake.params.get("extra", "")
java_opts = get_java_opts(snakemake)
log = snakemake.log_fmt_shell(stdout=True, stderr=True)

shell(
    "picard CollectRnaSeqMetrics "
    "{java_opts} {extra} "
    "INPUT={snakemake.input.bam} "
    "OUTPUT={snakemake.output} "
    "REF_FLAT={snakemake.input.refflat} "
    "STRAND_SPECIFICITY={strand} "
    "{log}"
)