PICARD COLLECTGCBIASMETRICS

Run picard CollectGcBiasMetrics to generate QC metrics pertaining to GC bias.

Example

This wrapper can be used in the following way:

rule alignment_summary:
    input:
        # BAM aligned to reference genome
        bam="mapped/a.bam",
        # reference genome FASTA from which GC-context is inferred
        ref="genome.fasta",
    output:
        metrics="results/a.gcmetrics.txt",
        chart="results/a.gc.pdf",
        summary="results/a.summary.txt",
    params:
        # optional additional parameters, for example,
        extra="--MINIMUM_GENOME_FRACTION 1E-5",
    log:
        "logs/picard/a.gcmetrics.log",
    # optional specification of memory usage of the JVM that snakemake will respect with global
    # resource restrictions (https://snakemake.readthedocs.io/en/latest/snakefiles/rules.html#resources)
    # and which can be used to request RAM during cluster job submission as `{resources.mem_mb}`:
    # https://snakemake.readthedocs.io/en/latest/executing/cluster.html#job-properties
    resources:
        mem_mb=1024,
    wrapper:
        "v3.8.0-49-g6f33607/bio/picard/collectgcbiasmetrics"

Note that input, output and log file paths can be chosen freely.

When running with

snakemake --use-conda

the software dependencies will be automatically deployed into an isolated environment before execution.

Notes

• The java_opts param allows for additional arguments to be passed to the java compiler, e.g. “-XX:ParallelGCThreads=10” (not for -XmX or -Djava.io.tmpdir, since they are handled automatically).

• The extra param allows for additional program arguments.

• –TMP_DIR is automatically set by resources.tmpdir

• For more information, see https://broadinstitute.github.io/picard/command-line-overview.html#CollectGcBiasMetrics

Software dependencies

• picard=3.1.1

• snakemake-wrapper-utils=0.6.2

Input/Output

Input:

• BAM file of RNA-seq data aligned to genome

• REF_FLAT formatted file of transcriptome annotations

Output:

• GC metrics text file

• GC metrics PDF figure

• GC summary metrics text file

Authors

• Brett Copeland

Code

__author__ = "Brett Copeland"
__copyright__ = "Copyright 2021, Brett Copeland"
__email__ = "brcopeland@ucsd.edu"
__license__ = "MIT"


import tempfile
from snakemake.shell import shell
from snakemake_wrapper_utils.java import get_java_opts

log = snakemake.log_fmt_shell()

extra = snakemake.params.get("extra", "")
java_opts = get_java_opts(snakemake)

with tempfile.TemporaryDirectory() as tmpdir:
    shell(
        "picard CollectGcBiasMetrics"
        " {java_opts} {extra}"
        " --INPUT {snakemake.input.bam}"
        " --TMP_DIR {tmpdir}"
        " --OUTPUT {snakemake.output.metrics}"
        " --CHART {snakemake.output.chart}"
        " --SUMMARY_OUTPUT {snakemake.output.summary}"
        " --REFERENCE_SEQUENCE {snakemake.input.ref}"
        " {log}"
    )