PICARD COLLECTINSERTSIZEMETRICS

Collect metrics on insert size of paired end reads with picard tools.

Example

This wrapper can be used in the following way:

rule insert_size:
    input:
        "mapped/{sample}.bam",
    output:
        txt="stats/{sample}.isize.txt",
        pdf="stats/{sample}.isize.pdf",
    log:
        "logs/picard/insert_size/{sample}.log",
    params:
        # optional parameters (e.g. relax checks as below)
        extra="--VALIDATION_STRINGENCY LENIENT --METRIC_ACCUMULATION_LEVEL null --METRIC_ACCUMULATION_LEVEL SAMPLE",
    # optional specification of memory usage of the JVM that snakemake will respect with global
    # resource restrictions (https://snakemake.readthedocs.io/en/latest/snakefiles/rules.html#resources)
    # and which can be used to request RAM during cluster job submission as `{resources.mem_mb}`:
    # https://snakemake.readthedocs.io/en/latest/executing/cluster.html#job-properties
    resources:
        mem_mb=1024,
    wrapper:
        "v4.6.0/bio/picard/collectinsertsizemetrics"

Note that input, output and log file paths can be chosen freely.

When running with

snakemake --use-conda

the software dependencies will be automatically deployed into an isolated environment before execution.

Notes

• The java_opts param allows for additional arguments to be passed to the java compiler, e.g. “-XX:ParallelGCThreads=10” (not for -XmX or -Djava.io.tmpdir, since they are handled automatically).

• The extra param allows for additional program arguments.

• –TMP_DIR is automatically set by resources.tmpdir

• For more information see, https://broadinstitute.github.io/picard/command-line-overview.html#CollectInsertSizeMetrics

Software dependencies

• picard=3.2.0

• r-base=4.4.1

• snakemake-wrapper-utils=0.6.2

Input/Output

Input:

• bam file

Output:

• txt: textual representation of metrics

• pdf: insert size histogram

Authors

• Johannes Köster

Code

__author__ = "Johannes Köster"
__copyright__ = "Copyright 2016, Johannes Köster"
__email__ = "johannes.koester@protonmail.com"
__license__ = "MIT"


import tempfile
from snakemake.shell import shell
from snakemake_wrapper_utils.java import get_java_opts

log = snakemake.log_fmt_shell()

extra = snakemake.params.get("extra", "")
java_opts = get_java_opts(snakemake)


with tempfile.TemporaryDirectory() as tmpdir:
    shell(
        "picard CollectInsertSizeMetrics"
        " {java_opts} {extra}"
        " --INPUT {snakemake.input}"
        " --TMP_DIR {tmpdir}"
        " --OUTPUT {snakemake.output.txt}"
        " --Histogram_FILE {snakemake.output.pdf}"
        " {log}"
    )