PICARD MARKDUPLICATESWITHMATECIGAR

Mark PCR and optical duplicates with picard tools, taking into account the CIGAR of the mate.

URL:

Example

This wrapper can be used in the following way:

rule mark_duplicates:
    input:
        "mapped/{sample}.bam",
    output:
        bam="dedup/{sample}.bam",
        metrics="dedup/{sample}.metrics.txt",
    log:
        "logs/picard/dedup/{sample}.log",
    params:
        extra="--REMOVE_DUPLICATES true",
    # optional specification of memory usage of the JVM that snakemake will respect with global
    # resource restrictions (https://snakemake.readthedocs.io/en/latest/snakefiles/rules.html#resources)
    # and which can be used to request RAM during cluster job submission as `{resources.mem_mb}`:
    # https://snakemake.readthedocs.io/en/latest/executing/cluster.html#job-properties
    resources:
        mem_mb=1024,
    wrapper:
        "v1.2.1/bio/picard/markduplicateswithmatecigar"

Note that input, output and log file paths can be chosen freely.

When running with

snakemake --use-conda

the software dependencies will be automatically deployed into an isolated environment before execution.

Software dependencies

• picard=2.26
• snakemake-wrapper-utils==0.1.3

Input/Output

Input:

• bam file

Output:

• bam file with marked or removed duplicates

Notes

• The java_opts param allows for additional arguments to be passed to the java compiler, e.g. “-XX:ParallelGCThreads=10” (not for -XmX or -Djava.io.tmpdir, since they are handled automatically).
• The extra param allows for additional program arguments.
• –TMP_DIR is automatically set by resources.tmpdir
• For more information see, https://broadinstitute.github.io/picard/command-line-overview.html#MarkDuplicatesWithMateCigar

Authors

• Johannes Köster
• Filipe G. Vieira

Code

__author__ = "Johannes Köster"
__copyright__ = "Copyright 2016, Johannes Köster"
__email__ = "koester@jimmy.harvard.edu"
__license__ = "MIT"


import tempfile
from snakemake.shell import shell
from snakemake_wrapper_utils.java import get_java_opts

log = snakemake.log_fmt_shell(stdout=True, stderr=True, append=True)

extra = snakemake.params.get("extra", "")
java_opts = get_java_opts(snakemake)


with tempfile.TemporaryDirectory() as tmpdir:
    shell(
        "picard MarkDuplicatesWithMateCigar"
        " {java_opts} {extra}"
        " --INPUT {snakemake.input}"
        " --TMP_DIR {tmpdir}"
        " --OUTPUT {snakemake.output.bam}"
        " --METRICS_FILE {snakemake.output.metrics}"
        " {log}"
    )