GATK3 REALIGNERTARGETCREATOR

Run gatk3 RealignerTargetCreator

Example

This wrapper can be used in the following way:

rule realignertargetcreator:
    input:
        bam="mapped/{sample}.bam",
        ref="genome.fasta",
        known="dbsnp.vcf.gz",
    output:
        intervals="{sample}.intervals",
        java_temp=temp(directory("gatk3_indelrealigner/{sample}")),
    log:
        "logs/gatk/realignertargetcreator/{sample}.log",
    params:
        extra="", # optional
    resources:
        mem_mb=1024,
    threads: 16
    wrapper:
        "bio/gatk3/realignertargetcreator"

Note that input, output and log file paths can be chosen freely.

When running with

snakemake --use-conda

the software dependencies will be automatically deployed into an isolated environment before execution.

Notes

• The java_opts param allows for additional arguments to be passed to the java compiler, e.g. “-XX:ParallelGCThreads=10” (memory is automatically inferred from resources and temp dir from output.java_temp.
• The extra param allows for additional program arguments.
• For more information see, https://github.com/broadinstitute/gatk-docs/blob/master/gatk3-tutorials/(howto)_Perform_local_realignment_around_indels.md
• Gatk3.jar is not included in the bioconda package, i.e it need to be added to the conda environment manually.

Software dependencies

• gatk==3.8
• snakemake-wrapper-utils==0.1.3

Input/Output

Input:

• bam file
• reference genome
• bed file (optional)
• vcf files known variation (optional)

Output:

• target intervals
• temp dir (optional)

Authors

• Patrik Smeds
• Filipe G. Vieira

Code

__author__ = "Patrik Smeds"
__copyright__ = "Copyright 2019, Patrik Smeds"
__email__ = "patrik.smeds@gmail.com.com"
__license__ = "MIT"

import os

from snakemake.shell import shell
from snakemake_wrapper_utils.java import get_java_opts

extra = snakemake.params.get("extra", "")
java_opts = get_java_opts(snakemake)


bed = snakemake.input.get("bed", "")
if bed:
    bed = "-L " + bed


known = snakemake.input.get("known", "")
if known:
    if isinstance(known, str):
        known = "-known {}".format(known)
    else:
        known = list(map("-known {}".format, known))


log = snakemake.log_fmt_shell(stdout=True, stderr=True)


shell(
    "gatk3 {java_opts} -T RealignerTargetCreator"
    " -nt {snakemake.threads}"
    " {extra}"
    " -I {snakemake.input.bam}"
    " -R {snakemake.input.ref}"
    " {known}"
    " {bed}"
    " -o {snakemake.output.intervals}"
    " {log}"
)