GATK APPLYBQSR

Run gatk ApplyBQSR.

URL: https://gatk.broadinstitute.org/hc/en-us/articles/9570337264923-ApplyBQSR

Example

This wrapper can be used in the following way:

rule gatk_applybqsr:
    input:
        bam="mapped/{sample}.bam",
        ref="genome.fasta",
        dict="genome.dict",
        recal_table="recal/{sample}.grp",
    output:
        bam="recal/{sample}.bam",
    log:
        "logs/gatk/applybqsr/{sample}.log",
    params:
        extra="",  # optional
        java_opts="",  # optional
    resources:
        mem_mb=1024,
    wrapper:
        "v9.4.1/bio/gatk/applybqsr"


rule gatk_applybqsr_cram:
    input:
        bam="mapped/{sample}.bam",
        ref="genome.fasta",
        dict="genome.dict",
        recal_table="recal/{sample}.grp",
    output:
        bam="recal/{sample}.cram",
    log:
        "logs/gatk/applybqsr/{sample}.cram.log",
    params:
        extra="",  # optional
        java_opts="",  # optional
        embed_ref=False,  # embed the reference in cram output
    resources:
        mem_mb=1024,
    wrapper:
        "v9.4.1/bio/gatk/applybqsr"


rule gatk_applybqsr_cram_embed:
    input:
        bam="mapped/{sample}.bam",
        ref="genome.fasta",
        dict="genome.dict",
        recal_table="recal/{sample}.grp",
    output:
        bam="recal/{sample}.embed.cram",
    log:
        "logs/gatk/applybqsr/{sample}.embed.cram.log",
    params:
        extra="",  # optional
        java_opts="",  # optional
        embed_ref=True,  # embed the reference in cram output
    resources:
        mem_mb=1024,
    wrapper:
        "v9.4.1/bio/gatk/applybqsr"

Note that input, output and log file paths can be chosen freely.

When running with

snakemake --use-conda

the software dependencies will be automatically deployed into an isolated environment before execution.

Notes

• The java_opts param allows for additional arguments to be passed to the java compiler, e.g. “-XX:ParallelGCThreads=10” (not for -XmX or -Djava.io.tmpdir, since they are handled automatically).

• The extra param allows for additional program arguments.

Software dependencies

• gatk4=4.6.2.0

• snakemake-wrapper-utils=0.8.0

• samtools=1.23.1

Input/Output

Input:

• BAM file

• FASTA reference

• recalibration table for the bam

Output:

• recalibrated bam file

Authors

• Christopher Schröder

• Johannes Köster

• Jake VanCampen

• Filipe G. Vieira

Code

__author__ = "Christopher Schröder"
__copyright__ = "Copyright 2020, Christopher Schröder"
__email__ = "christopher.schroeder@tu-dortmund.de"
__license__ = "MIT"


import tempfile
from snakemake.shell import shell
from snakemake_wrapper_utils.java import get_java_opts

# Extract arguments
extra = snakemake.params.get("extra", "")
embed_ref = snakemake.params.get("embed_ref", False)
java_opts = get_java_opts(snakemake)

log = snakemake.log_fmt_shell(stdout=True, stderr=True, append=True)

if snakemake.output.bam.endswith(".cram"):
    embed = " --output-fmt-option embed_ref" if embed_ref else ""
    output = "/dev/stdout"
    pipe_cmd = "| samtools view --with-header --reference {snakemake.input.ref} --output-fmt cram {embed} --output {snakemake.output.bam}"
else:
    output = snakemake.output.bam
    pipe_cmd = ""

with tempfile.TemporaryDirectory() as tmpdir:
    shell(
        "(gatk --java-options '{java_opts}' ApplyBQSR"
        " --input {snakemake.input.bam}"
        " --bqsr-recal-file {snakemake.input.recal_table}"
        " --reference {snakemake.input.ref}"
        " {extra}"
        " --tmp-dir {tmpdir}"
        " --output {output}" + pipe_cmd + ") {log}"
    )