GATK3 INDELREALIGNER

Run gatk3 IndelRealigner

URL:

Example

This wrapper can be used in the following way:

rule indelrealigner:
    input:
        bam="mapped/{sample}.bam",
        bai="mapped/{sample}.bai",
        ref="genome.fasta",
        known="dbsnp.vcf.gz",
        known_idx="dbsnp.vcf.gz.tbi",
        target_intervals="{sample}.intervals"
    output:
        bam="realigned/{sample}.bam",
        bai="realigned/{sample}.bai",
        java_temp=temp(directory("/tmp/gatk3_indelrealigner/{sample}")),
    log:
        "logs/gatk3/indelrealigner/{sample}.log"
    params:
        extra=""  # optional
    threads: 16
    resources:
        mem_mb = 1024
    wrapper:
        "bio/gatk/indelrealigner"

Note that input, output and log file paths can be chosen freely.

When running with

snakemake --use-conda

the software dependencies will be automatically deployed into an isolated environment before execution.

Software dependencies

  • gatk==3.8
  • snakemake-wrapper-utils==0.1.3

Input/Output

Input:

  • bam file
  • reference genome
  • target intervals to realign
  • bed file (optional)
  • vcf files known variation (optional)

Output:

  • indel realigned bam file
  • indel realigned bai file (optional)
  • temp dir (optional)

Notes

Authors

  • Patrik Smeds
  • Filipe G. Vieira

Code

__author__ = "Patrik Smeds"
__copyright__ = "Copyright 2019, Patrik Smeds"
__email__ = "patrik.smeds@gmail.com.com"
__license__ = "MIT"

import os

from snakemake.shell import shell
from snakemake_wrapper_utils.java import get_java_opts


extra = snakemake.params.get("extra", "")
java_opts = get_java_opts(snakemake)


bed = snakemake.input.get("bed", "")
if bed:
    bed = "-L " + bed


known = snakemake.input.get("known", "")
if known:
    if isinstance(known, str):
        known = "-known {}".format(known)
    else:
        known = list(map("-known {}".format, known))


output_bai = snakemake.output.get("bai", None)
if output_bai is None:
    extra += " --disable_bam_indexing"


log = snakemake.log_fmt_shell(stdout=True, stderr=True)


shell(
    "gatk3 {java_opts} -T IndelRealigner"
    " {extra}"
    " -I {snakemake.input.bam}"
    " -R {snakemake.input.ref}"
    " {known}"
    " {bed}"
    " --targetIntervals {snakemake.input.target_intervals}"
    " -o {snakemake.output.bam}"
    " {log}"
)